Calculadora avanzada y simulador de restaurante
Calculadora avanzada descripción:
Es una calculadora que puede calcular: suma, resta multiplicación, división, potencia, raíz cuadrada, logaritmo natural, seno, coseno, tangente, cotangente, secante y cosecante. Se puede usar varias veces hasta que el usuario ponga la opción de salir
Código del programa:
Algoritmo Calculadora_Avanzada
//Elaborado por: Nixon Piguave Montaño
Definir op, num1, num2, resultado Como Real //definimos las variables que se usaran en el programa op para las opciones, num1 y num2 para los valores a calcular, y resultado para almacenar el resultado de las operaciones correspondientes
Repetir
Escribir "|----Bienvenido a su calculadora avanzada----|"
Escribir "1. Suma"
Escribir "2. Resta"
Escribir "3. Multiplicación"
Escribir "4. División"
Escribir "5. Potencia"
Escribir "6. Seno"
Escribir "7. Coseno"
Escribir "8. Tangente"
Escribir "9. Cotangente"
Escribir "10. Secante"
Escribir "11. Cosecante"
Escribir "12. Raíz Cuadrada"
Escribir "13. Logaritmo natural"
Escribir "0. Salir"
Escribir "Elija una opción:"
Leer op
si op >= 0 y op <=13 Entonces //Esta estructura es para que no permita poner numeros que no sean los que estan en las opciones y si ponen uno le saldra un msj que diga opcion invalida
Segun op hacer //La estructura segun es para de acuerdo a la opcion que pongas, te saldra su operacion correspondiente
1:
Escribir "Suma de dos numeros"
Escribir "Ingrese el primer numero"
Leer num1
Escribir "Ingrese el segundo numero"
Leer num2
resultado = num1 + num2
Escribir num1, " + ", num2, " = ", resultado
2:
Escribir "Resta de dos numeros"
Escribir "Ingrese el primer numero"
Leer num1
Escribir "Ingrese el segundo numero"
Leer num2
resultado = num1 - num2
Escribir num1, " - ", num2, " = ", resultado
3:
Escribir "Multiplicacion"
Escribir "Ingrese el primer numero"
Leer num1
Escribir "Ingrese el segundo numero"
Leer num2
resultado = num1 * num2
Escribir num1, " * ", num2, " = ", resultado
4:
Escribir "Division"
Escribir "Ingrese el primer numero"
Leer num1
Escribir "Ingrese el segundo numero"
Leer num2
Si num2 <> 0 Entonces //Esta estructura esta para que mientras que el segundo valor sea diferente de cero se pueda hacer la operacion, caso contrario mostrara un msj con su error
resultado = num1 / num2
Escribir num1, " / ", num2, " = ", resultado
Sino
Escribir "Error: No se puede dividir por cero."
Fin Si
5:
Escribir "Potencia"
Escribir "Ingrese el primer"
Leer num1
Escribir "Ingrese el exponente"
Leer num2
resultado = num1 ^ num2
Escribir num1, " elevado a la ", num2, " = ", resultado
6:
Escribir "Seno de un numero"
Escribir "Ingrese un numero (valor dado en radianes)"
Leer num1
resultado = sen(num1)
Escribir "seno de ", num1, " = ", resultado
7:
Escribir "Coseno de un numero (valor dado en radianes)"
Escribir "Ingrese un numero"
Leer num1
resultado = cos(num1)
Escribir "El coseno de ", num1, " = ", resultado
8:
Escribir "Tangente de un numero (valor dado en radianes)"
Escribir "Ingrese un numero"
Leer num1
resultado = tan(num1)
Escribir "La tangente de ", num1, " = ", resultado
9:
Escribir "Cotangente de un numero (valor dado en radianes)"
Escribir "Ingrese un numero"
Leer num1
resultado = cos(num1) / sen(num1)
Escribir "La cotangente de ", num1, " = ", resultado
10:
Escribir "Secante de un numero (valor dado en radianes)"
Escribir "Ingrese un numero"
Leer num1
resultado = 1/ cos(num1)
Escribir "La secante de ", num1, " = ", resultado
11:
Escribir "Cosecante de un numero (valor dado en radianes)"
Escribir "Ingrese un numero"
Leer num1
resultado = 1/ sen(num1)
Escribir "La cosecante de ", num1, " = ", resultado
12:
Escribir "Raíz Cuadrada de un numero"
Escribir "Ingrese un numero"
Leer num1
Si num1 >= 0 Entonces
resultado = Raiz(num1)
Escribir "La raiz cuadrada de ", num1, " es ", resultado
Sino
Escribir "Error: No se puede calcular la raíz cuadrada de un número negativo."
Fin Si
13:
Escribir "Logaritmo natural de un numero"
Escribir "Ingresa un número positivo"
Leer num1
Si num1 > 0 Entonces //Esta estructura es para que no permita valores menores o iguales a cero ya que como sabemos en un logaritmo natural no se puede agregar cero o numeros negativos
resultado = ln(num1)
Escribir "El logaritmo natural de ", num1, " es ", resultado
Sino
Escribir "Por favor, introduce un número positivo."
FinSi
Fin segun
SiNo
Escribir "Opcion invalida intente de nuevo"
FinSi
Escribir "-----Gracias por usar la Calculadora Avanzada.------"
Escribir "Presione una tecla para continuar"
Esperar Tecla //este es otro codigo integrado en pseint que no hara nada hasta que presiones un tecla para continuar, era necesario ya que si no el codigo de limpiar pantalla se ejecutara de inmediato y no nos permitiria observar el resultado de manera mas detallada
Limpiar Pantalla // "Limpiar pantalla es un codigo integrado dentro de pseint que borrara los datos en pantalla, esto lo uso para que cuando ya se haga una operacion y tenga que hacer otra la pantalla se vea mas limpia"
Hasta Que op = 0 //Fin de estructura repetir, que hara que el programa se repita hasta que opcion sera 0 (salir)
Fin Algoritmo
Ejecución del programa (calculadora avanzada):
Como su nombre lo indica simula un restaurante es decir tienes que pedir tu orden (elegir algo que quieras comer de lo que esta en el menú) y también pagar por lo que has pedido en total, en el programa a medida vas ordenando lo que vas a comer te muestra cuanto es lo que tienes que pagar con respecto a lo que has pedido hasta ese momento, también te da tu cambio cuando pagas con mas dinero del que pide
Código del programa:
Algoritmo Restaurante
//Elaborado por: Nixon Piguave Montaño
Definir opciones_menu Como Cadena //definimos las variables de acuerdo a los tipos de datos que se usaran en el programa
Definir menu Como Real
Definir total_pedido Como Real
Definir opcion_elegida Como Entero
Definir precio_pizza Como Real
Definir precio_hamburguesa Como Real
Definir precio_ensalada Como Real
Definir precio_pollo como Real
Definir precio_chaulafan como Real
Definir precio_carne_asada como Real
Definir precio_jugo_naranja como Real
Definir precio_jugo_mora como Real
Definir precio_coca_cola_personal como Real
Definir precio_coca_cola_grande como Real
Definir precio_consomé como Real
menu = 0 // El valor de menu es cero para poder almacenar el precio de varios ordenes y asi ir sumando el valor de menu a la otra variable que se llama "total_pedido"
total_pedido = 0
precio_pizza = 10.00
precio_hamburguesa = 5.00
precio_ensalada = 4.00
precio_pollo = 2.50
precio_chaulafan = 3.00
precio_carne_asada = 2.50
precio_jugo_naranja = 0.50
precio_jugo_mora = 0.50
precio_coca_cola_personal = 0.30
precio_coca_cola_grande = 1.60
precio_consomé = 1.50
opciones_menu = "1. Pizza (10.00) | 2. Hamburguesa (5.00) | 3. Ensalada (4.00) | 4. Pollo apanado (2.50) | 5. Chaulafan (3.00) | 6. Carne asada (2.50) | 7. Jugo de naranja (0.50) | 8. Jugo de mora (0.50) | 9. Coca cola personal (0.30) | 10. Coca cola grande (1.60) | 11. Consome (1.50) | 12. Pagar"
Escribir "Menú del restaurante:"
Escribir opciones_menu
Repetir //usamos la estructura repetir para facilitar la opcion pagar y para poder pedir varias opciones
Escribir "Seleccione una opción (1-12): "
Leer opcion_elegida
Segun opcion_elegida Hacer //La estructura segun dentro de la repetir me parecio la mejor opcion para este tipo de situaciones en las que posiblemente haya que elegir varias opciones
1:
menu = precio_pizza
2:
menu = precio_hamburguesa
3:
menu = precio_ensalada
4:
menu = precio_pollo
5:
menu = precio_chaulafan
6:
menu = precio_carne_asada
7:
menu = precio_jugo_naranja
8:
menu = precio_jugo_mora
9:
menu = precio_coca_cola_personal
10:
menu = precio_coca_cola_grande
11:
menu = precio_consomé
12:
Escribir "Sus pedidos ya estan hechos acerquese a pagar"
De Otro Modo:
Si opcion_elegida < 1 o Opcion_elegida > 12 //Estas lineas de codigo son para evitar que el usuario ponga opciones que no estan en el programa por ejemplo la opcion 16
Escribir "Opción no válida. Por favor, elija una opción válida."
Fin Si
Fin Segun
Si opcion_elegida <> 12 Entonces //esta estructura es para poder seguir eligiendo varias ordenes hasta que la opcion elegida sea 12
total_pedido = total_pedido + menu //Esto es lo que va dando el total a pagar a medida vas ordenando y gracias a esto el valor de menu puede ir variando ya que su anterior valor fue almacenado aqui
Escribir "Pedido actual: $", menu
Escribir "Total acumulado: $", total_pedido
Fin Si
Hasta Que opcion_elegida = 12
Escribir "El total de su factura es: $", total_pedido
Repetir //La estructura repetir la use en este caso para que mientras que la cantidad que pago no sea mayor o igual al total a pagar el programa siga pidiendo un pago
Escribir "Por favor, introduzca la cantidad a pagar: "
Leer pago
Si pago < total_pedido Entonces
Escribir "Lo siento, el pago es insuficiente. Por favor, pague la cantidad exacta."
Fin Si
Hasta Que pago >= total_pedido
cambio = pago - total_pedido //Esta linea de codigo es la que me proporciona un cambio en caso de que mi cantidad pagada sea mayor a la que tenia que pagar
Escribir "Gracias por su pago. Su cambio es: $", cambio, " tenga buen dia!"
FinAlgoritmo
Ejecución del programa (Simulador de restaurante):
Comentarios
Publicar un comentario